***VERY DETAILED + HIGH QUALITY*** Guitar Hero Bluetooth Connect Tutoial

This tutorial will show you step by step how to connect a wii guitar for guitar hero to your computer and allow you to play with it. Very easy to understand and high quality. Please rate/comment I would appreciate constructive criticism for how I can improve my next video. Thanks :D

GlovePie download site: http://www.plunder.com/GlovePIE-v0-30-download-105502.htm

Copy ALL OF the below into GlovePie:

// Guitar Hero 3 Wii Controler for Guitar Hero 3 GlovePIE script
//
// This script is configured to make the Wii Guitar act the same
// as the default guitar hero keyboard settings
// Also, don't forget to turn off lefty flip as Guitar Hero will turn
// That on by default if you're set to keyboard in settings
//
//Note: This was chosen because guitar hero refuses to recognize
// The PPJoy virtual joystick as the guitar hero guitar
// Other games that allow joystick configuration coulde be
// setup using PPJoy, allowing the whammy bar to be analog.


// Debug List Setup
var.dummy = Wiimote.RawForceX
if Wiimote.Classic.a then var.G = "Green" else var.G = ""
if Wiimote.Classic.b then var.R = "Red" else var.R = ""
if Wiimote.Classic.x then var.Y = "Yellow" else var.Y = ""
if Wiimote.Classic.y then var.B = "Blue" else var.B = ""
if Wiimote.Classic.ZL then var.O = "Orange" else var.O= ""
if Wiimote.Classic.Minus then var.Minus = "-" else var.Minus = ""
if Wiimote.Classic.Plus then var.Plus = "+" else var.Plus = ""
if Wiimote.Classic.Up then var.Strum = "StrumUp" elseif Wiimote.Classic.Down then var.Strum = "StrumDown" else var.Strum = ""
debug = "Frets: "+var.G+var.R+var.Y+var.B+var.O+var.Minus+var.Plus+"; Strum: "+var.Strum+"; Whammy:"+Wiimote.Classic.R+var.RF+"; Tilt=" + Wiimote.RawForceZ+"; Joystick: X = "+Wiimote.Classic.Joy1X+", Y = "+Wiimote.Classic.Joy1Y;

/*
---BUTTON MAPPING to Keyboard and Mouse--
Configuration:

Green - V
Red - C
Yellow - X
Blue - Z
Orange - Left Shift
Strum Up - Left Mouse Button
Strum Down - Right Mouse Button
Minus - Middle Mouse Button
Plus - Escape
Tilt - Middle Mouse Button
Whammy - Right Alt
Joystick Up - Up
Joystick Down - Down
Joystick Right - Right
Joystick Left - Left
*/

// Guitar Joystick

Key.Left = (-1.2 < Wiimote.Classic.Joy1X < -0.5) // Joystick moving Left = minus X axis
Key.Right = (0.5 < Wiimote.Classic.Joy1X < 1.2) // Joystick moving Right = positive X axis
Key.Up = (-1.2 < Wiimote.Classic.Joy1Y < -0.5) // Joystick moving Up = negative Y axis
Key.Down = (0.5 < Wiimote.Classic.Joy1Y < 1.2) // Joystick moving Down = positive Y axis

// Fret Buttons

Key.V = Wiimote.Classic.a //Green
Key.C = Wiimote.Classic.b //Red
Key.X = Wiimote.Classic.x //Yellow
Key.Z = Wiimote.Classic.y //Blue
Key.LeftShift = Wiimote.Classic.ZL //Orange

// Plus and Minus Buttons

Mouse.MiddleButton = Wiimote.Classic.Minus //Star Power
Key.Escape = Wiimote.Classic.Plus //Menu / Pause


// Strum Bar

Mouse.LeftButton = Wiimote.Classic.Up //Strum Up
Mouse.RightButton = Wiimote.Classic.Down //Strum Down

// Press the Right Alt button (Whammy) when the whammy bar is depressed
// To tweak the timing of how far down you need to tilt the whammy
// bar to hit the key, alter the value to the left of < Wiimote
// For Referance, my whammy ranges from 0.52 at rest to 0.84 fully pressed

Key.RightAlt = (0.6 < Wiimote.Classic.R < 0.9)

// Press the Middle Mouse Button (Star Power) if the guitar is tilted
// To tweak the tilt timing, alter the value to the left of < Wiimote
// Make it lower to trigger sooner, raise it to trigger later
// For reference, I recorded a 24-25 value when completely vertical
// A roughly 45 degree tilt has a value of 14-15
// And a horizontal guitar read -1-0

Mouse.MiddleButton = (20 < Wiimote.RawForceZ < 100)

// LEDs - Turn on Player 1 LED, turn all others off
Wiimote1.LED1 = true;
Wiimote1.LED2 = false;
Wiimote1.LED3 = false;
Wiimote1.LED4 = false;

//END OF FILE